Set_View ini and disk BufferS

January 24, 2006 on 7:54 pm | In Notetab Clips, Special Clips - for someone, test clips | No Comments

Reposted 2/2/06
Here are revised, REVISED, clips, one to use NoteTabs users inifile feature to store tidbits of information, the other, to use disk files as a temporary storage medium.

For setting new buffers the clip uses the first word in the selection, if it is descriptive enough you can accept that name or type over with your own name choice.

Both approaches appear to work well, the disk file method doesn’t have the text selection size limitations of the ini file storage method.

Both approaches store a variable in memory at buffer creation. If you perform an action that wipes the variable, change or close the clipbook, close NoteTab, shut down the computer, you can regenerate the memory variable.

Go into the View_Set mode, select the buffers for which you want to regenerate memory variables, as you step thru each buffer view the variable is reset.

BOTH CLIPS ARE ON THIS PAGE.

<>····················<>
Set_View ini BufferS

Select between Markers, Add to ClipBook.

<>------------Marker------------<>
H="Set_View ini BufferS"
;_ Modified-Updated~Created_20060202
;_ hrs ø hsavage·pobox·com_11:05:59a
^!ClearVariables
^!Set %ww%=^$IsWordWrap$
^!SetScreenUpdate 0
^!SetIniFile ^$GetLibraryPath$Buffers
; - if no selection made, opens buffers.ini or exits
^!If ^$GetSelSize$ < 11 OPENFILE
; - seizes first word of selection as buffer name, can be typed over
^!Set %add%=^?{NAME BUFFER ADDITION=^$GetWord$}
^!Set %add%=^$StrReplace(" ";"_";^$StrTrim("^%add%")$;0;0)$
^!SaveValue ^$StrUpper("^%add%")$=^$GetSelection$
^!Select 0
; ·-·-·
; - switch comment from 'p_' line to set "permanent Variable"
^!Set %^$StrLower("^%add%")$%=^$GetValue("^%add%")$
;^!Set %p_^$StrLower("^%add%")$%=^$GetValue("^%add%")$
; ·-·-·
^!Goto REAL_END
; ·-·-·-·-·
:OPENFILE
^!IfFileExist ^$GetLibraryPath$Buffers.ini NEXT ELSE EXIT
^!Open ^$GetLibraryPath$Buffers.ini /j=1
^!SetWordWrap 0
; ·-·-·-·-·
:MAKE_LIST
; - loops thru and lists keys
^!Find ^[A-Z0-9_]+= RS
^!IfError SET_ARRAY
^!Set %extract%=^$StrReplace("=";"";"^$GetSelection$|";0;0)$
^!Append %list%=^%extract%
^!Goto MAKE_LIST
; ·-·-·-·-·
:SET_ARRAY
; - shows an array of key names
^!Set %list%=^$StrDeleteRight("^%list%";1)$
^!SetListDelimiter |
^!SetArray %list%=^?{(H=26;T=A)INI-BUFFER/S TO CHOOSE!==^%list%}; %bfr_action%=^?{VIEW BUFFERS, SET VARS -- DEL BUFFERS, CLEAR VARS==_VIEW_SET|DEL_CLEAR|VIEW_ONLY-ALL_BUFFERS}
; ·-·-·
:VIEW_ONLY-ALL_BUFFERS
; - to view buffer only, make no selection
^!If "^%list%" = "" EXIT ELSE ^!Close DISCARD
^!Set %loop%=0; %count%=^%list0%
; ·-·-·-·-·
:LOOP
^!Inc %loop%
^!Set %bfr_key%=^$GetValue("^%list^%loop%%")$
; ·-·-·
; - clears, resets chosen variable
^!ClearVariable %^$StrLower("^%list^%loop%%")$%
^!ClearVariable %p_^$StrLower("^%list^%loop%%")$%
; - switch comment from 'p_' line to set "permanent Variable"
^!Set %^$StrLower("^%list^%loop%%")$%=^%bfr_key%
;^!Set %p_^$StrLower("^%list^%loop%%")$%=^%bfr_key%
; ·-·-·
^!Goto ^%bfr_action%
; ·-·-·-·-·
:VIEW_SET
^!Info [L]TIDBIT·····^%list^%loop%%^%nl%^%nl%^%bfr_key%
^!Goto ANOTHER_LOOP?
; ·-·-·-·-·
:DEL_CLEAR
; - delete key, clear associated variable,
^!ClearValue ^%list^%loop%%
; ·-·-·
; - switch comment from 'p_' line to clear "permanent Variable"
^!ClearVariable ^%list^%loop%%
;^!ClearVariable %p_^%list^%loop%%%
; ·-·-·-·-·
:ANOTHER_LOOP?
^!If ^%loop% < ^%count% LOOP
; ·-·-·-·-·
:REAL_END
^!StatusClose
^!SetWordWrap ^%ww%
<>------------Marker------------<>

Number of Valid Clip-lines=76

<>··········Separator··········<>

Set_View Disk BufferS

Select between Markers, Add to ClipBook.

<>------------Marker------------<>
H="Set_View Disk BufferS"
;_ Modified-Updated~Created_20060202
;_ hrs ø hsavage·pobox·com_12:04:09a
; ·-·-·
; - Buffer names are restricted to characters
; - available for use in filenames
^!ClearVariables
^!SetScreenUpdate 0
^!Set %ww%=^$IsWordWrap$
; ·-·-·
^!Set %bfr_idx%="^$GetExpandedName(^##)$"
^!Set %bfr_dir%="^$GetDocumentPath$Buffers\"
; ·-·-·
; - adjustable, unless selection is => 11 characters
; - clip diverts to view/clear section
^!If ^$GetSelSize$ < 11 SET_ARRAY
; ·-·-·
^!IfFileExist "^%bfr_dir%nul" SKIP_1 ELSE NEXT
^!MkDir "^%bfr_dir%"
; ·-·-·-·-·
:MAKE_BFR
^!Set %bfr_name%=^?{ENTER MAKE_BUFFER NAME=^$GetWord$}
^!Set %bfr_name%=^$StrReplace(" ";"_";^$StrTrim("^%bfr_name%")$;0;0)$
^!SetCode %bfr_txt%=^$GetSelection$
^!TextToFile "^%bfr_dir%^$StrUpper(^%bfr_name%)$" ^%bfr_txt%
; ·-·-·
; - switch comment from 'p_' line to set "permanent Variable"
;^!Set %^$StrLower("^%bfr_name%")$%="^%bfr_txt%"
^!Set %p_^$StrLower("^%bfr_name%")$%="^%bfr_txt%"
; ·-·-·
^!Goto REAL_END
; ·-·-·-·-·
:SET_ARRAY
^!SetListDelimiter |
^!Set %files%=^$GetFiles("^%bfr_dir%";"*.*";NAME)$
^!If ^%files%=^%EMPTY% END
^!Set %files%=^$StrReplace("^%bfr_dir%";"^%empty%";"^%files%";0;0)$
^!SetArray %files%=^?{(H=26;T=A)BUFFER FILE TO CHOOSE!==^%files%}; %bfr_action%=^?{Open-Set vars, View-Set vars, DEL Files, Clear Vars==OPEN_SET|_VIEW_SET|DEL_CLEAR}
; ·-·-·
;_END_IF_NO_CHOICE
^!IfTrue ^$IsEmpty(^%files%)$ NEXT ELSE SKIP_3
^!StatusShow NO FILE SELECTED
^!Delay 25
; ·-·-·
^!Goto REAL_END
; ·-·-·
^!Set %loop%=0; %count%=^%files0%
; ·-·-·-·-·
:LOOP
^!Inc %loop%
^!Set %bfr_name%=^$GetFileName(^%files^%loop%%)$
^!SetCode %bfr_txt%=^$GetFileText("^%bfr_dir%^%bfr_name%")$
; ·-·-·
; - switch comment from 'p_' line to set "permanent Variable"
;^!SetCode %^$StrLower("^%bfr_name%")$=^%bfr_txt%
^!SetCode %p_^$StrLower("^%bfr_name%")$%=^%bfr_txt%
; ·-·-·
^!Goto ^%bfr_action%
; ·-·-·-·-·
:OPEN_SET
; - this will open the buffer file as an ordinary file
^!Open ^%bfr_dir%^%bfr_name%
; ·-·-·
^!Goto ANOTHER_LOOP?
; ·-·-·-·-·
:VIEW_SET
; - this will display in an ^!Info [L] box, can be selected and pasted
^!Info [L]TIDBIT·····^%bfr_name%^%nl%^%nl%^%bfr_txt%
; ·-·-·
^!Goto ANOTHER_LOOP?
; ·-·-·-·-·
:DEL_CLEAR
; - ^!RecycleFile or ^!DeleteFile, to recycle or, delete from disk
^!RecycleFile "^%bfr_dir%^%bfr_name%"
; ·-·-·
; - switch comment from 'p_' line to set "permanent Variable"
;^!ClearVariable %^$StrLower("^%bfr_name%")$%
^!ClearVariable %p_^$StrLower("^%bfr_name%")$%
; ·-·-·-·-·
:ANOTHER_LOOP?
^!If ^%loop% < ^%count% LOOP
; ·-·-·-·-·
:REAL_END
^!StatusClose
^!SetWordWrap ^%ww%
<>------------Marker------------<>

Number of Valid Clip-lines=85

Scramble_Multi Words

January 14, 2006 on 7:40 am | In General, Notetab Clips, Special Clips - for someone | No Comments

This clip, when run on normal text scrambles the characters in 4 letter words and above without altering the formatting of the text. It leaves the first and last characters of each word unchanged but scrambles the others.

I don’t know who’s responsible for the original algorithm but a writer, he thought it might make interesting reading, located an old clip named ‘JabberWords’ thru Google.

It would scramble most words but would leave some unscrambled, to be expected when randomizing any sequence. I modified the clip so it would not leave any unscrambled words of 4 characters or greater. Although, some 4 letter words are impossible to scramble in this manner.

Words such as seek, keep, been or look and others will not change.

This is the first paragraph, above, in scrambled form;

Tihs cilp, wehn run on nmraol txet sbraelcms the crhcartaes in 4 lteetr wdors and avboe wtuohit atrneilg the fiatorntmg of the txet. It lavees the frist and lsat caarchrets of ecah wrod ucanehgnd but slmrecabs the oherts.

Scramble_Multi Words

Cut and Paste what’s between the markers.


<>------------Marker------------<>
H="Scramble_Multi"
;_ Modified-Updated~Created_20060107
;_ hrs ø hsavage·pobox·com_11:09:29p
^!ClearVariables
; -place cursor in line where scrambling to start
^!Select LINE
^!Select 0
^!Set %rowCol%=^$GetRow$:^$GetCol$
^!Set %letters%=[a-zA-Z']
^!Set %letters4%=^%letters%^%letters%^%letters%^%letters%
^!SetScreenUpdate 0
;
:LOOP
^!Find "^%letters4%+" RS
^!IfError END_LOOP
;
:BASEDUP
^!Set %baseDup%=^$GetSelection$
^!Set %baseWord%=^$GetSelection$
^!Set %baseLen%=^$StrSize(^%baseWord%)$
; checks for 4 character words and handles accordingly.
^!If ^%baseLen% = 4 NEXT ELSE SCRAMBLE
^!If ^$StrCopy("^%baseWord%";2;1)$ <> ^$StrCopy("^%baseWord%";3;1)$ SCRAMBLE
;
:REWORD
; if scrambling is passed sets newWord = baseWord
^!Set %newWord%=^%baseWord%
^!Goto PASS
;
:SCRAMBLE
^!Set %firstChar%=^$StrIndex(^%baseWord%;1)$
^!Set %lastChar%=^$StrIndex(^%baseWord%;^%baseLen%)$
^!Set %newLen%=^$Calc(^%baseLen%-2)$
^!Set %baseWord%=^$StrCopy(^%baseWord%;2;^%newLen%)$
^!Set %randSort%=^%empty%
;
:BUILD_LOOP
^!if ^%baseWord%=^%empty% END_BUILD_LOOP
^!Set %randSort%=^%randSort%< ^$StrRandom(9;01)$>^$StrIndex(^%baseWord%;1)$^%nl%
^!Set %baseWord%=^$StrCopy(^%baseWord%;2;100)$
^!Goto BUILD_LOOP
;
:END_BUILD_LOOP
^!Set %sortedBlock%=^$StrSort(^%randSort%;0;1;0)$
^!Set %randWord%=^$StrStripHTML(^%sortedBlock%;0)$
^!Set %newWord%=^%firstChar%^$StrReplace(" ";^%empty%;^%randWord%;1;0)$^%lastChar%
;
; if newWord = baseWord, jumps
^!IfSame "^%newWord%" "^%baseDup%" BASEDUP
;
:PASS
^%newWord%
^!Jump SELECT_END
^!Goto LOOP
;
:END_LOOP
^!SetScreenUpdate 1
^!SetCursor ^%rowCol%
<>------------Marker------------<>

Number of Valid Clip-lines=58

ImageWrap

January 12, 2006 on 5:31 am | In Notetab Clips, Special Clips - for someone | No Comments

Select between the markers and paste into a new file named – ImageWrap.clb. Place in the Notetab Libraries folder

I’m having a problem getting this to display correctly to enable you to get a correct copy/paste.

If you copy/paste this library everything should be normal, except, double quotes. You will have to do a Search/Replace, search for – &quot; -, replace with the regular double quote character.


<>------------Marker------------<>
= V5 MultiLine NoSorting TabWidth=30

H="ReLoad Starting Files"
; in case you stop mid-clip and want to reload the
; files that were loaded when you started the clip.
^!OpenFavorites ImageWrap
^!DeleteFile ^$GetFavoritePath$ImageWrap.fvr

H=";Image_Wrap - IMPORTANT"
==========================================
Adapted, by many, from an original by Joe Barta jbarta@apk.net

http://junior.apk.net/~jbarta/image-wrap/

fortiter at gmail dot com
;_ Modified-Updated~Created_20060111
;_ hrs ø hsavage·pobox·com_06:50:10p
==========================================

"THIS LIBRARY 'AUTOMATICALLY SAVES AND CLOSES ALL OPEN FILES WHEN RUN'. WHEN IMAGEWRAP FINISHES FILES THAT WERE CLOSED, ARE RE-OPENED." You do not have to close files manually.

Convert a group of images into a suite of HTML pages linked from a single index page.

THE INDEX FILE MUST BE CREATED IN A DIRECTORY ABOVE - CLOSER TO THE ROOT FOLDER - (OR IN THE SAME DIRECTORY AS) THE IMAGES.

Click 'Begin New Pic_Index', make appropriate choices in dialogs and clips will build wrapper for the selected picture files.

When Selecting Pictures, Each Group In The Same Folder Must Be Selected As A Group, Re_Do The Image Loop To Select Pictures In Different Folders.

You Can Customize The Html Files By Digging Into The Clips "_Wrapper" And "_Index".

H="; ···················"

H="Build New Pic_Index"
^!ClearVariables
^!SetScreenUpdate 0
^!SaveFavorites ImageWrap
^!Close ALL,SAVE
;
^!Save As ^?[(T=S;F="All Files (*.*)|*.*")CHOOSE IMAGE FOLDER AND SAVE YOUR INDEX FILE=piclist.html]
;
^!Set %imagewrap_doc%=^$GetExpandedName(^##)$
^!Set %base_path%=^$GetPath(^$StrDeleteLeft("^%imagewrap_doc%";2)$)$
^!Set %base_path%=^$StrReplace("\";"/";"^%base_path%";0;0)$
^!Set %base_path%=file:///C|^%base_path%
;
^!Set %bgcolor%=^?[BACKGROUND COLOR (SELECT OR ENTER HEX CODE)=_FFFFFF (White)^=FFFFFF|000000 (Black)^=000000]
;
^!Set %txtcolor%=^?[TEXT COLOR (SELECT OR ENTER HEX CODE)=FFFFFF (White)^=FFFFFF|_000000 (Black)^=000000]
;
^!Set %doc_title%=^?[SET A TITLE FOR HTML FILES? (Leave Blank For None)=Image Collection]
;
^!Set %p_size%=^?[(H=9)Change DEFAULT to FRACTIONAL size, BETTER to VIEW.==100%^=1.0|90%^=.9|80%^=.8|70%^=.7|_60%^=.6|50%^=.5|40%^=.4|30%^=.3]
^!SetWordWrap 0
;
^!StatusShow Select Pictures In 1 Folder, Click Ok, Re_Do The Image Loop To Pick More Pictures.
^!Delay 40
^!StatusClose
;
:IMAGESELECT
^!Jump DOC_END
^?{(T=O;S=M;F="Image files (*.jpg;*.gif;*.png)|*.jpg;*.gif;*.png")CHOOSE IMAGE FILES, (Can repeat for files in different folders)}^%nl%
;
; Make item-per-line list removing semi-colons or quotes
^!Replace ";" >> "^P" TIWHSA
^!Replace """ >> "" TIWHSA
^!Skip IMAGE LIST COMPLETE, NO TO PICK MORE, YES/NO?
^!Goto IMAGESELECT
;
:PROCESS
; get the base path_1 of the file list
^!Set %base_path_1%=^$GetPath(^$GetDocName$)$
;
; get the name of file
^!Set %base_name_1%=^$GetFileName(^$GetDocName$)$
;
; get the total lines and initialize line count
^!Set %total_lines%=^$GetLineCount$
^!Set %current_line_number%=1
;
; Set up a pasteboard
^!ToolBar New Document
;
; go to loop
^!FarClip ImageWrap:OPERATE
;
; tidy up on return
; kill the pasteboard
^!Document LAST
^!DestroyDoc
;
; now we're at the file list
^!Select ALL
^!FarClip ImageWrap:Pic_Index
^!Close "^%imagewrap_doc%" SAVE
;
^!OpenFavorites ImageWrap
^!DeleteFile ^$GetFavoritePath$ImageWrap.fvr
^!Open ^%imagewrap_doc%
^!SetDocIndex ^$GetDocIndex("^%imagewrap_doc%")$
^!Prompt All done!

H="_Operate"
^!SetWordWrap 0
^!Document FIRST
^!SetCursor ^%current_line_number%:1
^!Select EOL
^!ToolBar Copy
;
; grab image particulars
^!Set %full_disk_path%=^$GetClipboard$
;
^!Set %img_width%="^$Calc(^$GetImgWidth(^$GetClipboard$)$*^%p_size%;0)$"
;
^!Set %img_height%="^$Calc(^$GetImgHeight(^$GetClipboard$)$*^%p_size%;0)$"
;
^!Set %image_name%=^$GetName(^$GetClipboard$)$
^!Set %image_ext%=^$GetExt(^$GetClipboard$)$
;
; get the relative disk & web path of the image to the file list
^!Document NEXT
^!ToolBar Clear All
^!InsertText ^%full_disk_path%
^!Replace "^%base_path_1%" >> "" TIWHSA
^!Replace "\" >> "/" TIWHSA
^!Select EOL
^!ToolBar Cut
^!Set %relative_web_path%=^$GetClipboard$
;
; build a save as filename out of the full_disk_path
^!ToolBar Clear All
^!InsertText ^%full_disk_path%
;
^!Replace ".gif" >> "_gif" TIWHSA
^!Replace ".jpg" >> "_jpg" TIWHSA
^!Replace ".png" >> "_png" TIWHSA
^!Select EOL
^!ToolBar Cut
^!Set %full_disk_html_path%=^$GetClipboard$.html
;
; build a href out of the relative web path
^!ToolBar Clear All
^!InsertText ^%relative_web_path%
;
^!Replace ".gif" >> "_gif" TIWHSA
^!Replace ".jpg" >> "_jpg" TIWHSA
^!Replace ".png" >> "_png" TIWHSA
^!Select EOL
^!ToolBar Cut
^!Set %href_html_path%=^$GetClipboard$.html
;
; make a nifty wrapper file
^!ToolBar New Document
;
^!FarClip ImageWrap:WRAPPER
^!Save As ^%full_disk_html_path%
^!ToolBar Close Document
;
^!Set %link%=<li><a href="^%href_html_path%">^%image_name%(^%image_ext%)</a></li>
;
; go to the list and insert the link in place of the existing line
^!Document FIRST
^!SetCursor ^%current_line_number%:1
^!Select EOL
^!ToolBar Cut
^!InsertText ^%link%
;
; Stop when line count gets to the end of the list
^!Set %current_line_number%=^$Calc(^%current_line_number%+1;0)$
^!IF ^%current_line_number% = ^%total_lines% EXIT
^!FarClip ImageWrap:OPERATE
;
:EXIT

H="_Wrapper"
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>^%doc_title%</title>
<!-- Created with ImageWrap

http://junior.apk.net/~jbarta/image-wrap/

modified by don from http://htmlfixit.com
fortiter at gmail dot com
Modified-Updated~Created_20060109
hrs ø hsavage·pobox·com_07:00:59p
-->
<style type="text/css">
<!--
body {background-color:#^%bgcolor%;}
h2, li, li a {color:#^%txtcolor%;}
-->
</style>
</head>

<body>

<p><a href="^%base_path%^%base_name_1%">Return to Image Menu</a></p>
<center>
<img src="^%image_name%^%image_ext%"
width="^%img_width%"
height="^%img_height%"
alt="^%image_name%"
border="0" />

</center>

</body>
</html>

H="_Pic_Index"
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>^%doc_title%</title>
<!-- Created with ImageWrap

http://junior.apk.net/~jbarta/image-wrap/

modified by don from http://htmlfixit.com
fortiter at gmail dot com
Modified-Updated~Created_20060109
hrs ø hsavage·pobox·com_07:00:59p
-->
<style type="text/css">
<!--
body {background-color:#^%bgcolor%;}
h2, li, li a {color:#^%txtcolor%;}
-->
</style>
</head>

<body>

<h2>^%doc_title%</h2>
<ul>
^&
</ul>
</body>
</html>

H="; ···················"
<>------------Marker------------<>

CliP_uuE_uuD

January 7, 2006 on 1:19 am | In Administrative Clips, Notetab Clips | No Comments

This clip is to UUencode/UUdecode clip for sending to our lists via email. Email, most times, wraps long lines and after copying and pasting from the email, makes restoring to a working clip very difficult at times.

UU, encoding and decoding encodes the text with a straight right margin which is narrower than the email default width, thus, no wrapped lines.

The clip is written so that it pastes a copy of itself after the encoded text. The user must copy the appropriate section of the email to a new file, at that time copy the encode/decode clip to a clipbook and then the user will be able to decode the encoded portion of the new ‘temporary’ file very easily.

After decoding, cut and paste the decoded clip into a clipbook and give it a whirl. It works flawlessly for me but some may run into trouble, if so, just respond to the clips list

CliP_uuE_uuD


<>------------Marker------------<>
H="_CliP_uuE_uuD"
;_ Modified-Updated~Created_20060111
;_ hrs ø hsavage·pobox·com_11:22:30p
^!Clearvariables
;
; - this line should be removed for others use
^!Set %c1%=^$DecToChar(94)$; %c2%=^$DecToChar(94)$^$DecToChar(164)$
;
; - determines whether file is encoded or not
; - if selection is greater than 'nn' characters clip assumes ENCODE
^!If ^$GetSelSize$ > 79 ENCODE ELSE DECODE
;
:ENCODE
; - to encode, run clip, select(mark) text, press Ctrl
^!SetHintInfo Select Text, CTRL To CONTINUE, SHIFT+CTRL To END!!
^!StatusShow Select Text, CTRL To CONTINUE, SHIFT+CTRL To END!!
; - loops while selecting text, press Ctrl to Continue
^!Delay 1
;
^!IfFalse ^$IsCtrlKeyDown$ SKIP_-1
^!IfTrue ^$Calc(^$IsShiftKeyDown$*^$IsCtrlKeyDown$)$ EXIT
^!IfTrue ^$IsCtrlKeyDown$ SKIP_-1
;
^!KeyBoard Ctrl+C
;
; - copies and encodes text to variable
; - lines kept short for email
^!SetCode %uu_E%="^$StrReplace("^%c1%";"^%c2%";"^$GetClipboard$";0;0)$"
^!SetCode %uu_E%=^$StrUUEncode("^%uu_E%")$
^!Delay 2
^!SetCode %trailer%=^%nl%^%nl%H="^$GetClipName$"^%nl%
^!SetCode %trailer%=^%trailer%^$GetClipText(^$GetClipName$)$
^!Delay 2
^!ActivateApp
^!Menu File/New
^!SetHintInfo Select Destination, PRESS SHIFT To Paste!!
^!StatusShow Select Destination, PRESS SHIFT To Paste!!
;
; - loops while selecting paste location,
; - press SHIFT to Continue
^!Delay 1
^!IfFalse ^$IsShiftKeyDown$ SKIP_-1
^!IfTrue ^$Calc(^$IsShiftKeyDown$*^$IsCtrlKeyDown$)$ EXIT
^!IfTrue ^$IsShiftKeyDown$ SKIP_-1
^!StatusClose
;
; - inserts header, encoded text - ^%uu_E% -and a copy of
; - the clip - ^%trailer% - that encodes/decodes it
^!Set %marker%=<>------------Marker------------<>^%nl%
;
^!IfFileExist "^$GetDocumentPath$uuencode.hdr" NEXT ELSE SKIP
^!InsertText ^$GetFileText(^$GetDocumentPath$uuencode.hdr)$
^!InsertCode ^%nl%^%nl%^%marker%^%uu_E%^%trailer%^%marker%
^!Save AS "^$GetSpecialPath(DeskTop)$uu_Encoded.en"
^!Goto END
;
:DECODE
; - to decode, place cursor anywhere within the
; - encoded text. don't select it
; - finds and selects upper and lower encoded text limits
^!Find "^begin 600" IWRS
^!IfError END
^!Set %begin%=^$GetRow$
^!Replace "^begin 600.*\n" >> "begin 600\s\n" RS
^!Find "^`\nend" IRS
^!IfError END
^!MoveCursor +1
^!SelectTo ^%begin%:1
; - copies encoding to clipboard and prepares re-inserts it
^!SetCode %uu_D%=^$StrUUDecode("^$GetSelection$")$
^!KeyBoard BACKSPACE
^!InsertSelect ^%uu_D%^%nl%^%nl%H=";···············"^%nl%
^!Replace "^%c2%" >> "^%c1%" TWHSA
^!Menu Modify/E-Mail/UnQuote Text
^!RenameDoc "uu_Decoded.de"
^!Save
;
:END
^!ClipBoardRestore
^!Jump 1
<>------------Marker------------<>

Number of Valid Clip-lines=80

NoteTab Googler

January 6, 2006 on 11:06 pm | In Notetab Clips, test clips | 1 Comment

Using NoteTab to Google was discussed on the Clips List. This is a modified version of Don’s clip. This uses a basic default choice but still allows user input in the second entry point in the same wizard.

The second clip contains many of the terms you might search for relating to NoteTab. Some multiple choices(entries) work together, some don’t. Not being familiar with Google I don’t know why some will, and some will not work.

Both clips are needed, the second constitutes the choice list utilized by the first clip and can be edited to suit.

NoteTab Googler


H="NoteTab Googler"
;_Modified-Updated~Created
;_20060105_11:14:07a_hsavage a-t pobox d-o-t com
;*** Search Google for Notetab Messages
;*** based on Utilities Library + RP Doolings Idea
;*** don a-t htmlfixit d-o-t com
;
^!ClearVariables
^!If ^$GetSelSize$ > 4 HaveSelection ELSE NoSelection
:HAVESELECTION
^!Set %SearchTerm%=^$GetSelection$
^!Goto TheSearch
:NOSELECTION
^!SetListDelimiter |
^!SetWizardTitle "Pick Search TermS"
^!SetWizardLabel "Search Terms, Primary, Secondary, Tertiary, etc."
;
^!Set %SearchTerm%=^$StrTrim("^$GetClipText(SearchTerms)$")$
^!Set %SearchTerm%=^$StrReplace("^p";"|";"^%SearchTerm%";0;0)$
^!Set %ExtraTerm%=^$SetDefaultValue(^%SearchTerm%;^%empty%)$
^!Set %SearchTerm%=^?{(H=17)"Choose One Here, Choose and Enter Others Below"==^%SearchTerm%}; %ExtraTerm%=^?{Choose One and/or Type Additional Terms Separated By Spaces=^%ExtraTerm%}
;
^!Set %SearchTerm%=^$StrTrim("^$StrReplace("; ";"";"^%SearchTerm% ^%ExtraTerm%";0;0)$")$
^!Set %SearchTerm%=^$StrReplace(" ";"+";"^$StrUpper("^%SearchTerm%")$";0;0)$
^!Goto TheSearch
:THESEARCH
; - replace all spaces in search term with +
^!URL http://www.google.com/search?q=site%3Ahttp%3A%2F%2Fgroups.yahoo.com+notetab+^%SearchTerm%

H="_SearchTerms"
_CLIPS
ACCESSIBILITY
ALBUM-EXPRESS
EZIMAGER
EZTHUMBS
HTML
MAILBAG
NEXTRELEASE
OFFTOPIC
OTL
OUTLINE
REGEX
SCRIPTS
SETDOCINDEX
STRRANDOM
TEMPLATE
THUMBNAILS
TPL
VARIABLES

FiXiT_UpLoadeR Prep

January 6, 2006 on 8:32 pm | In Administrative Clips, Notetab Clips | No Comments

This clip is made to convert clips for posting at fixit.com so they will display and users can easily download and not be required to make any changes to start using them.

I like this clip because it does the minimum number of changes to get a good display, also, it can be used to convert a single clip or a complete clipbook.

All conversion is done in set variables and a new blank file, the original remains unchanged.

FiXiT_4_CLIPS

<>------------Marker------------<>
H="FiXiT_4_CLIPS"
;_ Modified-Updated~Created_20060113
;_ hrs ø hsavage·pobox·com_01:50:13p
;
^!Clearvariables
^!SetWordWrap 0
^!Set %qu%=^$DecToChar(34)$
^!Set %and%=^$DecToChar(38)$
^!Set %marker%=<>------------Marker------------<>^%nl%
;
^!StatusShow Select Text Before Continuing, Read STATUS BAR For INFO!
^!SetHintInfo Press CTRL To CONTINUE, SHIFT+CTRL To END!!
; - loops while selecting text, press Ctrl to Continue
^!Delay 1
^!IfFalse ^$IsCtrlKeyDown$ SKIP_-1
^!IfTrue ^$Calc(^$IsShiftKeyDown$*^$IsCtrlKeyDown$)$ EXIT
^!IfTrue ^$IsCtrlKeyDown$ SKIP_-1
;
^!SetCode %fixit%=^$StrReplace("^%and%quot;";"|*and_quote*|";"^$GetSelection$";0;0)$
^!Menu File/New
^!SetCode %fixit%=^$StrReplace("|*and_quote*|";"^%and%amp;quot;";"^%fixit%";0;0)$
^!SetCode %fixit%=^$StrReplace("^%qu%";"^%and%quot;";"^%fixit%";0;0)$
;
^!InsertText Title if Needed^%nl%^%nl%^%nl%
^!Set %top%=^$GetRow$
^!InsertCode
^%nl%^%marker%
^!Set %top_row%=^$GetRow$
^!InsertCode ^%fixit%
^!Set %bottom_row%=^$GetRow$
^!InsertCode ^%marker%
^%nl%
^!InsertText Number of Valid Clip-lines=^$Calc(^%bottom_row%-^%top_row%)$
^!SelectTo ^%top%:1
^!Save AS "^$GetSpecialPath(DeskTop)$FiXiT_CLIPS.htmL"
^!Jump 1
<>————Marker————<>

Number of Valid Clip-lines=34

<>————Marker————<>

This clip is more for clips containing HTML code, other wise same as above.
FiXiT_4_HTML


<>------------Marker------------<>
H="FiXiT_4_HTML"
;_ Modified-Updated~Created_20060113
;_ hrs ø hsavage·pobox·com_01:58:10p
;
^!Clearvariables
^!SetWordWrap 0
^!Set %qu%=^$DecToChar(34)$
^!Set %and%=^$DecToChar(38)$
^!Set %md%=^$DecToChar(183)$
^!Set %marker%=<>------------Marker------------<>^%nl%
;
^!StatusShow Select Text Before Continuing, Read STATUS BAR For INFO!
^!SetHintInfo Press CTRL To CONTINUE, SHIFT+CTRL To END!!
; - loops while selecting text, press Ctrl to Continue
^!Delay 1
^!IfFalse ^$IsCtrlKeyDown$ SKIP_-1
^!IfTrue ^$Calc(^$IsShiftKeyDown$*^$IsCtrlKeyDown$)$ EXIT
^!IfTrue ^$IsCtrlKeyDown$ SKIP_-1
;
^!SetCode %fixit%=^$StrReplace("^%and%quot;";"|*and_quote*|";"^$GetSelection$";0;0)$
^!Menu File/New
^!InsertCode ^%fixit%
^!Menu Modify/Characters To HTML/ALL Special Characters
^!SetCode %fixit%=^$StrReplace("&quot;";"^%and%amp;quot;";"^$GetSelection$";0;0)$
^!SetCode %fixit%=^$StrReplace("|*and_quote*|";"^%and%amp;quot;";"^$GetSelection$";0;0)$
^!SetCode %fixit%=^$StrReplace("^%and%middot;";"^%md%";"^%fixit%";0;0)$
;
^!InsertText Title if Needed^%nl%^%nl%^%nl%
^!Set %top%=^$GetRow$
^!InsertCode <code>^%nl%^%marker%
^!Set %top_row%=^$GetRow$
^!InsertCode ^%fixit%
^!Set %bottom_row%=^$GetRow$
^!InsertCode ^%marker%</code>^%nl%
^!InsertText Number of Valid Clip-lines=^$Calc(^%bottom_row%-^%top_row%)$
^!SelectTo ^%top%:1
^!Save AS "^$GetSpecialPath(DeskTop)$FiXiT_HTML.htmL"
^!Jump 1
<>------------Marker------------<>

Number of Valid Clip-lines=38

Clip to Prepare Clips for Posting on this Site

January 6, 2006 on 5:12 am | In Administrative Clips, Notetab Clips | No Comments

When we prepare clips, we need to do a little work to get them ready. Quotes often turn into smart quotes. That appears to be an issue with our posting software. Sometimes it does and sometimes it doesn’t add smart quotes. It also chokes often because it mistakes the greater than and less than signs for example as html tags. Because of that we need to prepare a clip before posting it.

Here is a first try at a clip we can use to prepare a clip for posting:
;make sure we aren't wrapped
^!SetWordWrap Off
;fix problem caused if clip actually
;contains &quot; in it
^!Replace "&quot;" >> "|*and_quote*|" ACIWS
;convert quotes and other characters to html
^!Keyboard ALT+M &10 R &10 A
^!Replace """ >> "&quot;" ATIWS
;undo the original &quot; characters
^!Replace "|*and_quote*|" >> "&amp;quot;" ACIWS
;count lines and insert number of lines
^!Jump Doc_End
^!Keyboard ENTER
^!InsertText ;line number ^$GetLineCount$
^!ToolBar Copy All
;line number 16

Notetab Clip to Search Google For Term

January 3, 2006 on 8:39 am | In General, Generic Clips, Notetab Clips | No Comments

Okay, I often search Google to find Notetab’s great Yahoogroups messages. I find the search utility in YahooGroups to be fairly limiting. Tonight RP Dooling — the author – suggested that a clip might be in order … and that got me to thinking. Here is the first in what could easily be a series of clips to search.

This one will limit its search to Yahoogroups that contain the word notetab, either the term you have highlighted when you select the clip, or in the alternative, it will prompt you for a search term to add. It then fires up Google an it is off to the races.

So here it is …
;*** Effort by Don Passenger
;*** don a-t htmlfixit d-o-t com
;*** discuss things live in chat at http://htmlfixit.com
;*** donations welcome at http://htmlfixit.com
;*** Search Google for Notetab Messages
;*** based on Utilities Library + RP Doolings Idea

;START
; Clear variables
^!ClearVariables
^!If ^$GetSelSize$ > 0 HaveSelection ELSE NoSelection

:HaveSelection
^!Set %SearchTerm%=^$GetSelection$
^!Goto TheSearch

:NoSelection
^!Set %SearchTerm%=^?{Type in All Search Terms Separated by a Space}
^!Goto TheSearch

:TheSearch
;replace all spaces in search term with +
^!Set %SearchTerm%=^$StrReplace(" ";"+";"^%SearchTerm%";0;0)$
;replace all quotes in search term with %22
^!Set %SearchTerm%=^$StrReplace(""";"%22";"^%SearchTerm%";0;0)$
^!URL http://www.google.com/search?q=site%3Ahttp%3A%2F%2Fgroups.yahoo.com+notetab+^%SearchTerm%
;line 25 if no lines are wrapped

Powered by WordPress with Pool theme design by Borja Fernandez.
Entries and comments feeds. Valid XHTML and CSS. ^Top^

Bad Behavior has blocked 489 access attempts in the last 7 days.